# Maintainer:

pkgname=st
pkgver=0.8.3
pkgrel=1
epoch=1
pkgdesc="Spinach's simple (suckless) terminal with a few patches" 
arch=('x86_64')
license=('MIT')
depends=('libxft')
makedepends=('ncurses' 'libxext' 'git')
config=('desktop-config.h')

sha256sums=('939ae3da237e7c9489694853c205c7cbd5f2a2f0c17fe41a07477f1df8e28552'
            'SKIP'
            '1b62ce4dbe25a4dc3e8b350cd5bbaa2097899ff2690774e895bbc8ce0756df5b'
            '9c5b4b4f23de80de78ca5ec3739dc6ce5e7f72666186cf4a9c6b614ac90fb285'
            'b43c113f0e8124f88803443d30a3c6e3e3e0f8c7d792f98fd1a0c4bbc383060f'
            '0f5ce33953abce74a9da3088ea35bf067a9a4cfeb9fe6ea9800268ce69e436c0')
            
_patches=("https://st.suckless.org/patches/blinking_cursor/st-blinking_cursor-20211116-2f6e597.diff"
          "https://st.suckless.org/patches/alpha/st-alpha-0.8.2.diff"
          "https://st.suckless.org/patches/alpha_focus_highlight/st-focus-20200731-43a395a.diff"
          "https://st.suckless.org/patches/clipboard/st-clipboard-0.8.3.diff")

source=("http://dl.suckless.org/st/$pkgname-$pkgver.tar.gz"
        "${config[0]}"
        "${_patches[@]}")

provides=("${pkgname}")
conflicts=("${pkgname}")

pkgver() {
    cd "${srcdir}/${pkgname}-${pkgver}"
	printf "%s" "$(awk '/^VERSION =/ {print $3}' config.mk)"
}

prepare() {
    cd "${srcdir}/${pkgname}-${pkgver}"
    ln -sf "${srcdir}/${config[0]}" config.h
    for patch in "${_patches[@]}"; do
        echo "Applying $(basename $patch)..."
        git apply "${srcdir}/$(basename $patch)"
    done
}

build() {
    cd "${srcdir}/${pkgname}-${pkgver}"
	make
}

package() {
    cd "${srcdir}/${pkgname}-${pkgver}"
	make PREFIX=/usr DESTDIR="${pkgdir}" install
	install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
	install -Dm644 README "${pkgdir}/usr/share/doc/${pkgname}/README.md"
}